1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright (C) 2013-2015 Free Software Foundation, Inc.
#
# This program is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the
# Free Software Foundation; either version 3, or (at your option) any
# later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; see the file COPYING3. If not see
# <http://www.gnu.org/licenses/>.
# This Awk script takes passes.def and writes pass-instances.def,
# counting the instances of each kind of pass, adding an instance number
# to everywhere that NEXT_PASS is used.
#
# For example, the single-instanced pass:
# NEXT_PASS (pass_warn_unused_result);
# becomes this in the output:
# NEXT_PASS (pass_warn_unused_result, 1);
#
# The various instances of
# NEXT_PASS (pass_copy_prop);
# become:
# NEXT_PASS (pass_copy_prop, 1);
# through:
# NEXT_PASS (pass_copy_prop, 8);
# (currently there are 8 instances of that pass)
# Usage: awk -f gen-pass-instances.awk passes.def
BEGIN {
print "/* This file is auto-generated by gen-pass-instances.awk";
print " from passes.def. */";
}
function handle_line()
{
line = $0;
# Find call expression.
where = match(line, /NEXT_PASS \((.+)\)/);
if (where == 0)
{
print line;
return;
}
# Length of the call expression.
len_of_call = RLENGTH;
len_of_start = length("NEXT_PASS (");
len_of_close = length(")");
# Find pass_name argument
len_of_pass_name = len_of_call - (len_of_start + len_of_close);
pass_starts_at = where + len_of_start;
pass_name = substr(line, pass_starts_at, len_of_pass_name);
# Set pass_counts
if (pass_name in pass_counts)
pass_counts[pass_name]++;
else
pass_counts[pass_name] = 1;
# Print call expression with extra pass_num argument
printf "%s, %s%s\n",
substr(line, 1, pass_starts_at + len_of_pass_name - 1),
pass_counts[pass_name],
substr(line, pass_starts_at + len_of_pass_name);
}
{ handle_line() }
# Local Variables:
# mode:awk
# c-basic-offset:8
# End:
|