blob: 2eb8c7a767015c74eb9edab556c9904592439e31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
//===-- floatundidf.s - Implement __floatundidf for x86_64 ----------------===//
//
// The LLVM Compiler Infrastructure
//
// This file is distributed under the University of Illinois Open Source
// License. See LICENSE.TXT for details.
//
//===----------------------------------------------------------------------===//
//
// This file implements __floatundidf for the compiler_rt library.
//
//===----------------------------------------------------------------------===//
// double __floatundidf(du_int a);
#ifdef __x86_64__
.const
.align 4
twop52: .quad 0x4330000000000000
twop84_plus_twop52:
.quad 0x4530000000100000
twop84: .quad 0x4530000000000000
#define REL_ADDR(_a) (_a)(%rip)
.text
.align 4
.globl ___floatundidf
___floatundidf:
movd %edi, %xmm0 // low 32 bits of a
shrq $32, %rdi // high 32 bits of a
orq REL_ADDR(twop84), %rdi // 0x1p84 + a_hi (no rounding occurs)
orpd REL_ADDR(twop52), %xmm0 // 0x1p52 + a_lo (no rounding occurs)
movd %rdi, %xmm1
subsd REL_ADDR(twop84_plus_twop52), %xmm1 // a_hi - 0x1p52 (no rounding occurs)
addsd %xmm1, %xmm0 // a_hi + a_lo (round happens here)
ret
#endif // __x86_64__
|
