summaryrefslogtreecommitdiff
path: root/lib/builtins/arm/divsi3.S
blob: ad96c9e5bfa966094009d8789b90e5b3af5d1f71 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
/*===-- divsi3.S - 32-bit signed integer divide ---------------------------===//
 *
 *                     The LLVM Compiler Infrastructure
 *
 * This file is dual licensed under the MIT and the University of Illinois Open
 * Source Licenses. See LICENSE.TXT for details.
 *
 *===----------------------------------------------------------------------===//
 *
 * This file implements the __divsi3 (32-bit signed integer divide) function
 * for the ARM architecture as a wrapper around the unsigned routine.
 *
 *===----------------------------------------------------------------------===*/

#include "../assembly.h"

#define ESTABLISH_FRAME \
    push   {r4, r7, lr}    ;\
    add     r7,     sp, #4
#define CLEAR_FRAME_AND_RETURN \
    pop    {r4, r7, pc}

   .syntax unified
   .text
#if defined(USE_THUMB_PROLOGUE)
   .thumb
#endif

	.p2align 3
// Ok, APCS and AAPCS agree on 32 bit args, so it's safe to use the same routine.
DEFINE_AEABI_FUNCTION_ALIAS(__aeabi_idiv, __divsi3)

@ int __divsi3(int divident, int divisor)
@   Calculate and return the quotient of the (signed) division.

#if defined(USE_THUMB_PROLOGUE)
DEFINE_COMPILERRT_THUMB_FUNCTION(__divsi3)
#else
DEFINE_COMPILERRT_FUNCTION(__divsi3)
#endif
#if __ARM_ARCH_EXT_IDIV__
   tst     r1,r1
   beq     LOCAL_LABEL(divzero)
   sdiv    r0, r0, r1
   bx      lr
LOCAL_LABEL(divzero):
   mov     r0,#0
   bx      lr
#else
ESTABLISH_FRAME
//  Set aside the sign of the quotient.
#  if __ARM_ARCH_ISA_THUMB == 1
    movs    r4,     r0
    eors    r4,     r1
#  else
    eor     r4,     r0, r1
#  endif
//  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
#  if   __ARM_ARCH_ISA_THUMB == 1
    asrs    r2,     r0, #31
    asrs    r3,     r1, #31
    eors    r0,     r2
    eors    r1,     r3
    subs    r0,     r0, r2
    subs    r1,     r1, r3
#  else
    eor     r2,     r0, r0, asr #31
    eor     r3,     r1, r1, asr #31
    sub     r0,     r2, r0, asr #31
    sub     r1,     r3, r1, asr #31
#  endif
//  abs(a) / abs(b)
    bl      SYMBOL_NAME(__udivsi3)
//  Apply sign of quotient to result and return.
#  if defined(USE_THUMB_1)
    asrs    r4,     #31
    eors    r0,     r4
    subs    r0,     r0, r4
#  else
    eor     r0,     r0, r4, asr #31
    sub     r0,     r0, r4, asr #31
#  endif
    CLEAR_FRAME_AND_RETURN
#endif
END_COMPILERRT_FUNCTION(__divsi3)

NO_EXEC_STACK_DIRECTIVE